通過N次試驗，終于知道如何編寫供C調用的匯編子程序
ICCavr中，參數通過r16/r17,r18/r19傳遞。
r16/r17是整體的，傳遞uchar和uint會全部占用，當uchar時，r17空置。
r18/r19同理。
如果還有參數要傳遞，則是通過Y指針指向的軟件堆棧傳遞。
每一個char和int都占用2個字節，如果是char，高字節空置。
也就是說，參數總要占用偶數個空間。
例如傳遞參數如下：
uchar *point1,uchar *point2,uchar data1,uchar data2,uchar data3
共5個參數
那么point1通過r16/r17傳遞，point2通過r18/r19傳遞
data1通過Y+0指向的軟件堆棧傳遞，data2通過Y+2指向的軟件堆棧傳遞，data3通過Y+4指向的軟件堆棧傳遞。
終于可以把俺的c程序大瘦身了，呵呵呵。
.s匯編文件
;多字節相加
;sum[number]+=add[number]
;void BytesAdd(uchar *sum,uchar *add,uchar number)
_BytesAdd::
clc ;c<-0
MOV r26,r16
MOV r27,r17 ;x<-sum
MOV r30,r18
MOV r31,r19 ;z<-add
ld r0,y ;r0<-number
balp:
ld r1,x
ld r2,z+
adc r1,r2 ;sum+=add+c
st x+,r1 ;store sum
dec r0
brne balp ;branch if number!=0
ret
;******************************************************
;多字節相減
;minuend[number]-=subtrahend[number]
;void BytesSub(uchar *minuend,uchar *subtrahend,uchar number)
_BytesSub::
clc ;c=0
MOV r26,r16
MOV r27,r17 ;x=minuend
MOV r30,r18
MOV r31,r19 ;z=subtrahend
ld r0,y ;r0=number
bslp:
ld r1,x
ld r2,z+
sbc r1,r2 ;minuend-=subtrahend+c
st x+,r1 ;store minuend
dec r0
brne bslp ;branch if number!=0
ret
;*******************************************************
C調用：
uchar sum[5],add[5];
uchar minuend[5],subtrahend[5];
BytesAdd(sum,add,5);//sum+=add,5bytes
BytesSub(minuend,subtrahend,5);//minuend-=subtrahend
|
|
66821730(技術支持)
